Embedding Tomcat and BlazeDS in an AIR 2.0 Application

In my previous post, I demonstrated how to create a simple Tomcat Launcher using the new AIR 2.0 Native Process API. The assumption in that sample was that Tomcat was already installed on your machine.

In this new sample application, I’m taking that idea a little further by embedding Tomcat as part of the native installer. The first time you run the application, Tomcat is automatically copied to your applicationStorageDirectory from where the AIR application starts it. In this sample, I still provide a simple console for the user to start and stop Tomcat manually, but in a real life application, you would probably want to start Tomcat automatically when the AIR application starts.

Why would you want to embed Tomcat as part of an AIR application? First of all, I’m not saying that you should… This is just part of my exploration of new capabilities in AIR 2.0. That being said, I can think of a number of use cases where this could make sense. For example:

• Tighter communication with Java code using BlazeDS locally as a way to directly invoke methods on remote Java classes.
• Provide an offline mode for an application that closely mimics the online infrastructure.

Installation Instructions

1. Download the AIR 2.0 beta runtime here.
2. Because Tomcat Launcher uses the Native Process API, I had to create native installers:
   • To install the application on Windows, download and run AIRAppWithEmbeddedTomcat.exe.
   • To install the application on a Mac, download and run AIRAppWithEmbeddedTomcat.dmg.

After starting the application, enter the path to your Java home folder, then click the Start button. The application will remember the folder you entered the next time you use the application. Try the “Embedded JSP Example” and “Embedded RemoteObject Example”. If you get a BindingException when you start Tomcat, make sure it isn’t already started. You can also click the Stop button to stop a running instance.

You can download the project here: AIRAppWithEmbeddedTomcat.fxp.zip. If you just want to take a quick peak at the code, here is AIRAppWithEmbeddedTomcat.mxml:

<?xml version="1.0" encoding="utf-8"?>
<!--
Christophe Coenraets http://coenraets.org
-->
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
					   xmlns:s="library://ns.adobe.com/flex/spark"
					   xmlns:mx="library://ns.adobe.com/flex/halo"
					   title="AIR Application with Embedded Tomcat"
					   height="600" width="800"
					   applicationComplete="init()">
	<s:layout>
		<s:VerticalLayout paddingLeft="8" paddingRight="8" paddingBottom="8" paddingTop="8"/>
	</s:layout>

	<fx:Script>
		<![CDATA[
			import mx.controls.Alert;

			private var startTomcatProcess:NativeProcess;
			private var stopTomcatProcess:NativeProcess;

			private var tomcatHomeDir:File;

			public function init():void
			{
				if (!NativeProcess.isSupported)
				{
					Alert.show("NativeProcess not supported");
				}

				tomcatHomeDir = File.applicationStorageDirectory.resolvePath("tomcat");
				if (!tomcatHomeDir.exists)
				{
					var tomcatOriginalDir:File = File.applicationDirectory.resolvePath("tomcat");
					trace("Copying tomcat to appStorageDirectory...");
					tomcatOriginalDir.copyTo(tomcatHomeDir);
				}
				tomcatHome.text = tomcatHomeDir.nativePath;				

				// Read the last home used to start Tomcat (if any)
				var xml:XML = readConfig();
				if (xml != null)
				{
					javaHome.text = xml.javaHome;
					return;
				}

				// If no known last home, present default/sample values
				if (Capabilities.os.toLowerCase().indexOf("win") > -1)
				{
					// default/sample values for Windows users
					javaHome.text = "C:\\Program Files\\Java\\jdk1.6.0";
				}
				else if (Capabilities.os.toLowerCase().indexOf("mac") > -1)
				{
					// default/sample values for Mac users
					javaHome.text = "/System/Library/Frameworks/JavaVM.framework/Versions/1.6.0";
				}

			}

			public function startTomcat():void
			{
				// Write the Java home path to config.xml so that it can be presented
				// to the user the next time the application is started
				writeConfig();

				log.text = "Starting Tomcat..." + File.lineEnding;
				startTomcatProcess = new NativeProcess();
				execute(startTomcatProcess, "start");
			}

			public function stopTomcat():void
			{
				log.text = "Stopping Tomcat..." + File.lineEnding;
				stopTomcatProcess = new NativeProcess();
				execute(startTomcatProcess, "stop");
			}

			public function execute(process:NativeProcess, arg:String):void
			{
				// Get a file reference to the JVM
				var file:File = new File(javaHome.text);
				if (Capabilities.os.toLowerCase().indexOf("win") > -1)
				{
					file = file.resolvePath("bin/javaw.exe");
				}
				else
				{
					file = file.resolvePath("Home/bin/java");
				}

				// Start the process
				try
				{
					var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();
					nativeProcessStartupInfo.executable = file;
					nativeProcessStartupInfo.workingDirectory = tomcatHomeDir.resolvePath("bin");
					var processArgs:Vector.<String> = new Vector.<String>();
					processArgs[0] = "-Dcatalina.home="+tomcatHomeDir.nativePath;
					processArgs[1] = "-classpath";
					processArgs[2] = tomcatHomeDir.resolvePath("bin/bootstrap.jar").nativePath;
					processArgs[3] = "org.apache.catalina.startup.Bootstrap";
					processArgs[4] = arg;
					nativeProcessStartupInfo.arguments = processArgs;
					startTomcatProcess = new NativeProcess();
					startTomcatProcess.start(nativeProcessStartupInfo);
					startTomcatProcess.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA,
						outputDataHandler);
					startTomcatProcess.addEventListener(ProgressEvent.STANDARD_ERROR_DATA,
						errorOutputDataHandler);
				}
				catch (e:Error)
				{
					Alert.show(e.message, "Error");
				}
			}

			public function outputDataHandler(event:ProgressEvent):void
			{
				var process:NativeProcess = event.target as NativeProcess;
				var data:String = process.standardOutput.readUTFBytes(process.standardOutput.bytesAvailable);
				log.text += data;
			}

			public function errorOutputDataHandler(event:ProgressEvent):void
			{
				var process:NativeProcess = event.target as NativeProcess;
				var data:String = process.standardError.readUTFBytes(startTomcatProcess.standardError.bytesAvailable);
				log.text += data;
			}

			private function readConfig():XML
			{
				var file:File = File.applicationStorageDirectory.resolvePath("config.xml");
				if (file.exists)
				{
					var fileStream:FileStream = new FileStream();
					fileStream.open(file, FileMode.READ);
					var xml:XML = XML(fileStream.readUTFBytes(fileStream.bytesAvailable));
					fileStream.close();
					return xml;
				}
				else
				{
					return null;
				}
			}

			private function writeConfig():void
			{
				var xml:String = '<?xml version="1.0" encoding="utf-8"?>' + File.lineEnding;
				xml += "<config>" + File.lineEnding;
				xml += "<javaHome>" + javaHome.text + "</javaHome>" + File.lineEnding;
				xml += "<tomcatHome>" + tomcatHome.text + "</tomcatHome>" + File.lineEnding;
				xml += "</config>" + File.lineEnding;

				var file:File = File.applicationStorageDirectory.resolvePath("config.xml");
				var fileStream:FileStream = new FileStream();
				fileStream.open(file, FileMode.WRITE);
				fileStream.writeUTFBytes(xml);
				fileStream.close();
			}

			private function openWithDefaultEditor():void
			{
				var file:File =
					File.createTempDirectory().resolvePath("tomcat_launcher_console.txt");
				var fileStream:FileStream = new FileStream();
				fileStream.open(file, FileMode.WRITE);
				fileStream.writeUTFBytes(log.text);
				fileStream.close();
				file.openWithDefaultApplication();
			}

		]]>
	</fx:Script>

	<fx:Declarations>
		<s:RemoteObject id="srv" destination="contacts"
						endpoint="http://localhost:8080/messagebroker/amf"/>
	</fx:Declarations>	

	<mx:TabNavigator width="100%" height="100%">

		<mx:VBox width="100%" height="100%" label="Console" paddingLeft="8" paddingRight="8" paddingBottom="8">

			<mx:Form width="100%">
				<mx:FormItem label="Java Home" width="100%">
					<s:TextInput id="javaHome" width="100%"/>
				</mx:FormItem>
				<mx:FormItem label="Embedded Tomcat Home" width="100%">
					<s:TextInput id="tomcatHome" width="100%" enabled="false"/>
				</mx:FormItem>
			</mx:Form>

			<s:HGroup>
				<s:Button label="Start" click="startTomcat()"/>
				<s:Button label="Stop" click="stopTomcat()"/>
				<s:Button label="Clear Console" click="log.text=''"/>
				<s:Button label="Open in Default Text Editor"
						  click="openWithDefaultEditor()"/>
			</s:HGroup>
			<s:TextArea id="log" width="100%" height="100%"/>

		</mx:VBox>

		<mx:VBox label="Embedded JSP Example" paddingLeft="8" paddingRight="8" paddingBottom="8">
			<mx:HTML id="html" width="100%" height="100%"/>
			<s:Button label="Load JSP" click="html.location='http://localhost:8080/hello.jsp'"/>
		</mx:VBox>

		<mx:VBox label="Embedded Remote Object Example" paddingLeft="8" paddingRight="8" paddingBottom="8">
			<mx:DataGrid width="100%" height="100%" dataProvider="{srv.findAll.lastResult}">
				<mx:columns>
					<mx:DataGridColumn dataField="id" headerText="Id"/>
					<mx:DataGridColumn dataField="firstName" headerText="First Name"/>
					<mx:DataGridColumn dataField="lastName" headerText="Last Name"/>
					<mx:DataGridColumn dataField="city" headerText="City"/>
				</mx:columns>
			</mx:DataGrid>
			<s:Button label="Get Data" click="srv.findAll()"/>
		</mx:VBox>

	</mx:TabNavigator>

</s:WindowedApplication>