AIR 2.0 Web Server using the New Server Socket API

After exploring Java integration using the new Native Process API (here and here), Excel integration using the new file.openWithDefaultApplication(), and the new Microphone API, here is another application I wrote, this time to explore the new Adobe AIR 2.0 Server Socket API.

The “Mini AIR Web Server” is a simplistic implementation of an HTTPServer. Needless to say that it is far from being a production quality Web Server. The goal here is simply to use the well understood mechanics of a web server to learn how to use server sockets in AIR 2.0.

Installation Instructions

1. Download the AIR 2.0 beta runtime here.
2. Download MiniAIRWebServer.air here.
3. Double-click MiniAIRWebServer.air in Explorer or Finder to start the installation process.

To test the application, open a browser and test the sample HTML pages provided with the application:

• http://localhost:8888/test1.html
• http://localhost:8888/test2.html
• http://localhost:8888/test3.html

NOTE: You may have to change the port number in these URLs depending on the port number you enter in the application.

You can add your own content in the webroot folder in the applicationStorageDirectory.

View Source is enabled, but if you just want to take a quick peak at the code, here is MiniAIRWebServer.mxml:

<?xml version="1.0" encoding="utf-8"?>
<!-- Author: Christophe Coenraets http://coenraets.org -->
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
					   xmlns:s="library://ns.adobe.com/flex/spark"
					   xmlns:mx="library://ns.adobe.com/flex/halo"
					   title="Mini AIR Web Server"
					   applicationComplete="init()" viewSourceURL="srcview/index.html">
	<s:layout>
		<s:VerticalLayout paddingTop="8" paddingLeft="8" paddingRight="8" paddingBottom="8"/>
	</s:layout>

	<fx:Script>
		<![CDATA[
			import flash.events.Event;
			import flash.events.ProgressEvent;
			import flash.events.ServerSocketConnectEvent;
			import flash.net.ServerSocket;
			import flash.net.Socket;
			import flash.utils.ByteArray;
			import mx.controls.Alert;

			private var serverSocket:ServerSocket;

			private var mimeTypes:Object = new Object();

			private function init():void
			{
				// The mime types supported by this mini web server
				mimeTypes[".css"] 	= "text/css";
				mimeTypes[".gif"] 	= "image/gif";
				mimeTypes[".htm"] 	= "text/html";
				mimeTypes[".html"] 	= "text/html";
				mimeTypes[".ico"] 	= "image/x-icon";
				mimeTypes[".jpg"] 	= "image/jpeg";
				mimeTypes[".js"] 	= "application/x-javascript";
				mimeTypes[".png"] 	= "image/png";

				// Initialize the web server directory (in applicationStorageDirectory) with sample files
				var webroot:File = File.applicationStorageDirectory.resolvePath("webroot");
				if (!webroot.exists)
				{
					File.applicationDirectory.resolvePath("webroot").copyTo(webroot);
				}
			}

			private function listen():void
			{
				try
				{
					serverSocket = new ServerSocket();
					serverSocket.addEventListener(Event.CONNECT, socketConnectHandler);
					serverSocket.bind(Number(port.text));
					serverSocket.listen();
					log.text += "Listening on port " + port.text + "...\n";
				}
				catch (error:Error)
				{
					Alert.show("Port " + port.text +
						" may be in use. Enter another port number and try again.\n(" +
						error.message +")", "Error");
				}
			}

			private function socketConnectHandler(event:ServerSocketConnectEvent):void
			{
				var socket:Socket = event.socket;
				socket.addEventListener(ProgressEvent.SOCKET_DATA, socketDataHandler);
			}

			private function socketDataHandler(event:ProgressEvent):void
			{
				try
				{
					var socket:Socket = event.target as Socket;
					var bytes:ByteArray = new ByteArray();
					socket.readBytes(bytes);
					var request:String = "" + bytes;
					log.text += request;
					var filePath:String = request.substring(4, request.indexOf("HTTP/") - 1);
					var file:File = File.applicationStorageDirectory.resolvePath("webroot" + filePath);
					if (file.exists && !file.isDirectory)
					{
						var stream:FileStream = new FileStream();
						stream.open( file, FileMode.READ );
						var content:ByteArray = new ByteArray();
						stream.readBytes(content);
						stream.close();
						socket.writeUTFBytes("HTTP/1.1 200 OK\n");
						socket.writeUTFBytes("Content-Type: " + getMimeType(filePath) + "\n\n");
						socket.writeBytes(content);
					}
					else
					{
						socket.writeUTFBytes("HTTP/1.1 404 Not Found\n");
						socket.writeUTFBytes("Content-Type: text/html\n\n");
						socket.writeUTFBytes("<html><body><h2>Page Not Found</h2></body></html>");
					}
					socket.flush();
					socket.close();
				}
				catch (error:Error)
				{
					Alert.show(error.message, "Error");
				}
			}

			private function getMimeType(path:String):String
			{
				var mimeType:String;
				var index:int = path.lastIndexOf(".");
				if (index > -1)
				{
					mimeType = mimeTypes[path.substring(index)];
				}
				return mimeType == null ? "text/html" : mimeType; // default to text/html for unknown mime types
			}

		]]>
	</fx:Script>

	<s:HGroup verticalAlign="middle">
		<s:Label text="Port:"/>
		<s:TextInput id="port" text="8888" width="50"/>
		<s:Button label="Listen" click="listen()"/>
	</s:HGroup>

	<s:TextArea id="log" width="100%" height="100%" />

</s:WindowedApplication>